Mercurial > ec-dotfiles

comparison vendor/vim-syntax/json.vim @ 508:bbcffc594d1e

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Vendor what should be vendored and add some more.
author edogawaconan <me@myconan.net>
date Mon, 17 Mar 2014 15:47:15 +0900
parents rc/vim-syntax-json@8ef5ddb9b54b
children 14b645f67f7c
comparison
equal deleted inserted replaced
507:973b7f21b582 508:bbcffc594d1e
1 " Vim syntax file
2 " Language: JSON
3 " Maintainer: Eli Parra <eli@elzr.com>
4 " Last Change: 2013-02-01
5 " Version: 0.12
6
7 if !exists("main_syntax")
8 if version < 600
9 syntax clear
10 elseif exists("b:current_syntax")
11 finish
12 endif
13 let main_syntax = 'json'
14 endif
15
16 syntax match jsonNoise /\%(:\|,\)/
17
18 " NOTE that for the concealing to work your conceallevel should be set to 2
19
20 " Syntax: Strings
21 if has('conceal')
22 syn region jsonString oneline matchgroup=jsonQuote start=/"/ skip=/\\\\\|\\"/ end=/"/ concealends contains=jsonEscape
23 else
24 syn region jsonString oneline matchgroup=jsonQuote start=/"/ skip=/\\\\\|\\"/ end=/"/ contains=jsonEscape
25 endif
26
27 " Syntax: JSON does not allow strings with single quotes, unlike JavaScript.
28 syn region jsonStringSQ oneline start=+'+ skip=+\\\\\|\\"+ end=+'+
29
30 " Syntax: JSON Keywords
31 " Separated into a match and region because a region by itself is always greedy
32 syn match jsonKeywordMatch /"[^\"\:]\+"[[:blank:]\r\n]*\:/ contains=jsonKeywordRegion
33 if has('conceal')
34 syn region jsonKeywordRegion matchgroup=jsonQuote start=/"/ end=/"\ze[[:blank:]\r\n]*\:/ concealends contained
35 else
36 syn region jsonKeywordRegion matchgroup=jsonQuote start=/"/ end=/"\ze[[:blank:]\r\n]*\:/ contained
37 endif
38
39 " Syntax: Escape sequences
40 syn match jsonEscape "\\["\\/bfnrt]" contained
41 syn match jsonEscape "\\u\x\{4}" contained
42
43 " Syntax: Numbers
44 syn match jsonNumber "-\=\<\%(0\|[1-9]\d*\)\%(\.\d\+\)\=\%([eE][-+]\=\d\+\)\=\>"
45
46 " ERROR WARNINGS **********************************************
47 "
48 " Syntax: Strings should always be enclosed with quotes.
49 syn match jsonNoQuotes "\<[[:alpha:]]\+\>"
50
51 " Syntax: An integer part of 0 followed by other digits is not allowed.
52 syn match jsonNumError "-\=\<0\d\.\d*\>"
53
54 " Syntax: Decimals smaller than one should begin with 0 (so .1 should be 0.1).
55 syn match jsonNumError "\:\@<=[[:blank:]\r\n]*\zs\.\d\+"
56
57 " Syntax: No comments in JSON, see http://stackoverflow.com/questions/244777/can-i-comment-a-json-file
58 syn match jsonCommentError "//.*"
59 syn match jsonCommentError "\(/\*\)\|\(\*/\)"
60
61 " Syntax: No semicolons in JSON
62 syn match jsonSemicolonError ";"
63
64 " Syntax: No trailing comma after the last element of arrays or objects
65 syn match jsonCommaError ",\_s*[}\]]"
66
67 " ********************************************** END OF ERROR WARNINGS
68 " Allowances for JSONP: function call at the beginning of the file,
69 " parenthesis and semicolon at the end.
70 " Function name validation based on
71 " http://stackoverflow.com/questions/2008279/validate-a-javascript-function-name/2008444#2008444
72 syn match jsonPadding "\%^[[:blank:]\r\n]*[_$[:alpha:]][_$[:alnum:]]*[[:blank:]\r\n]*("
73 syn match jsonPadding ");[[:blank:]\r\n]*\%$"
74
75 " Syntax: Boolean
76 syn keyword jsonBoolean true false
77
78 " Syntax: Null
79 syn keyword jsonNull null
80
81 " Syntax: Braces
82 syn region jsonFold matchgroup=jsonBraces start="{" end="}" transparent fold
83 syn region jsonFold matchgroup=jsonBraces start="\[" end="]" transparent fold
84
85 " Define the default highlighting.
86 " For version 5.7 and earlier: only when not done already
87 " For version 5.8 and later: only when an item doesn't have highlighting yet
88 if version >= 508 || !exists("did_json_syn_inits")
89 if version < 508
90 let did_json_syn_inits = 1
91 command -nargs=+ HiLink hi link <args>
92 else
93 command -nargs=+ HiLink hi def link <args>
94 endif
95 HiLink jsonPadding Operator
96 HiLink jsonString String
97 HiLink jsonEscape Special
98 HiLink jsonNumber Number
99 HiLink jsonBraces Operator
100 HiLink jsonNull Function
101 HiLink jsonBoolean Boolean
102 HiLink jsonKeywordRegion Label
103
104 HiLink jsonNumError Error
105 HiLink jsonCommentError Error
106 HiLink jsonSemicolonError Error
107 HiLink jsonCommaError Error
108 HiLink jsonStringSQ Error
109 HiLink jsonNoQuotes Error
110 HiLink jsonQuote Quote
111 HiLink jsonNoise Noise
112 delcommand HiLink
113 endif
114
115 let b:current_syntax = "json"
116 if main_syntax == 'json'
117 unlet main_syntax
118 endif
119
120 " Vim settings
121 " vim: ts=8 fdm=marker
122
123 " MIT License
124 " Copyright (c) 2013, Jeroen Ruigrok van der Werven, Eli Parra
125 "Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the Software), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
126 "The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
127 "THE SOFTWARE IS PROVIDED AS IS, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
128 "See https://twitter.com/elzr/status/294964017926119424